1 MBE Recipes
- 1.1 Bad Recipe
- 1.2 Good Recipe
- 1.3 Bad vs Good

MBE Recipes

Recipes operate the system.
Recipes also tell you and other growers what you did.
A recipe without comments is minimally useful. The more comments the better for when you or other growers look back at it.
The appreciation for comments goes in waves. - SRB
Following are bad and good recipes.

Bad Recipe

B121226A (not noted in recipe)

title (InGaAsSbN 1 QW grown at 350 C)

gr GaSb 1.235 ! A/sec
gr InGaSb 2.888  ! A/sec


waitop (waiting for user to check everything)
eval InTip_temp = 914.5


wait 00:15:00
T Sub 550 60
waituntil (549 < Sub < 551) 30

T InTip =  InTip_temp
open Sb
T SbValve 83
L GaSb 1000
T Sub 450 30
L GaSb 200
T Sub 350 15
L GaSb 800


comment (growing InGaAsSb QW)

repeat 1
T SbValve 165
T AsValve 158.8
L GaSb 10
L InGaAsSb 47.5
L InGaAsSbN 5
L InGaAsSb 47.5
T SbValve 83
T AsValve 0
L GaSb 200
er

T InTip 800


L GaSb 800

open Sb
T Sub 200 60
T BufferHTS 10 30


comment (waiting for sub to cool below 400C)
waituntil (200 < Sub < 400) 5
T SbValve 0
close Sb

T Sub 200

comment (done growing)

Good Recipe

B170123C

title (GaAs/AlAs Superlattice 20/200 A x30, Al 1153 C)
comment (B170123C)

! ****************************************
! Grower: NTS
! Description: GaAs/AlAs Superlattice 20/200 A x30, Al 1153 C
! Substrate: SI GaAs
! ****************************************

! ****************************************
! LAYER PLAN:
!  -- TOP --
!   (GaAs / AlAs : 20 A / 200 A) x30 SL, Al 1153 C
!   GaAs, 20 A
!   GaAs, 1500 A, 580 C
!  -- SUBSTRATE --
! ****************************************

! ****************************************
! ***** Define Growth Parameters *****
! * Growth Rates
! BG BF IG 1.73e-10 torr !updated
! BG GC IG 2.1e-10 torr !updated

! Target GaAs gr --> 2.0 A/sec from linear fit to other grower's GRs
! Target Ga BEP --> 2.27e-7
! Actual Ga BEP --> 2.2773e-7 !updated
! GaTip --> 1029.8 C !updated
gr GaAs 2 ! A/sec

! Target AlAs gr --> 2.0 A/sec from linear fit to other grower's GRs
! Target Al BEP --> 1.1e-7 ! target for sample A
! Actual Al BEP --> 1.248e-7 !updated - taken from STO
! AlBase --> 1153 C !updated
gr AlAs 2.02 ! A/s

! * As Valve Positions
! BG BF IG As open ~2.7564e-10 !updated
eval AsValve_deox = 250
! Target As BEP Ga --> 3.41e-6
! Actual As BEP Ga --> ~3.5599e-6 !updated
eval AsValve_GaAs = 238
! Target As BEP Al --> 2.2e-6
! Actual As BEP Al --> ~2.376e-6 !updated
eval AsValve_AlAs = 210

! * Substrate Thermocouple Temperatures
! Deox at ~600 degrees
! GaAs at 580 degrees
! AlAs at 580 degrees
eval t_Sub_deox = 740 
! from NTS B170123B
eval t_Sub_buffer = 720
! eval t_Sub_SL = 720


! ****************************************
! ***** DeOx *****
comment (Start recipe)
open As
t AsValve=AsValve_deox

eval t_Sub=t_Sub_deox-100
ramprate Sub 60
t Sub=t_Sub
waituntil ( t_Sub-1 < Sub < 999 ) 1
eval t_Sub=t_Sub_deox-30
ramprate Sub 40
t Sub=t_Sub
waituntil ( t_Sub-1 < Sub < 999 ) 1
ramprate Sub 20
t Sub=t_Sub_deox
waituntil ( t_Sub_deox-1 < Sub < 999 ) 10
wait 00:15:00
ramprate Sub 60


! ****************************************
! ***** Define Growth *****

! ***** Growth initialization *****
comment (Starting growth)
! open As ! Already opened by automated Deox
t Sub=t_Sub_buffer

! ***** Growing Buffer Layer *****
comment (Growing buffer)
t AsValve = AsValve_GaAs
L GaAs 1500
! 1500A/2A/s = 750 s = 12.5 min

! ***** Growing Pre SL GaAs Layer *****
comment (Growing Pre SL GaAs layer)
! ! t Sub=t_Sub_SL
t AsValve = AsValve_GaAs
L GaAs 20

! ***** Growing SL *****
comment (Growing GaAs:AlAs SL x30)
repeat 30
t AsValve = AsValve_AlAs
L AlAs 200 ! A
t AsValve = AsValve_GaAs
L GaAs 20 ! A
er
! SL ends on GaAs layer

! ***** End Growth *****
t Sub 200 60
comment (Waiting for Sub to cool below 400C)
waituntil (20 < Sub < 400) 2
t AsValve 5
wait 5
close As

comment (Done growing)
! ***** Done *****
! ****************************************

Bad vs Good

Bad recipe lacks:

Descriptive Title (is incomplete compared to database entry)
Sample ID, Date, and Grower name
Growth plan
Cell temperatures or BEPs
Any Group V info
Clear organization
Notes and comments

Good recipe has:

Everything the bad recipe lacks
- Descriptive Header
- Good info on G-III and Group V cell temperatures and fluxes
- Clear sections incl. a clear Deox part
- Ample comments